Sublime Security medium experimental mql

Attachment: ICS file with embedded email

Detects inbound messages containing ICS calendar attachments where a parsed event includes an embedded RFC822 email as a base64-encoded attachment rather than a simple URL reference. This technique smuggles a nested email payload inside a calendar invite, often to evade attachment scanning or deliver malicious content indirectly.

View Source

Detection Logic

type.inbound
and any(attachments,
        (
          .file_type == "ics"
          or .file_extension == "ics"
          or .content_type in ("application/ics", "text/calendar")
        )
        //
        // This rule makes use of a beta feature and is subject to change without notice
        // using the beta feature in custom rules is not suggested until it has been formally released
        //
        and any(beta.file.parse_ics(.).events,
                // .md5 proves the payload is embedded base64, not a Gmail ?view=att URL reference
                any(.attachments, .md5 is not null)
                and (
                  any(.attachments, .file_extension == "eml")
                  or any(.raw_properties,
                         .name == "ATTACH"
                         and any(.params,
                                 .name == "FMTTYPE"
                                 and "message/rfc822" in .values
                         )
                  )
                )
        )
)

Field Validations

Loading…

Comments (0)

Loading comments...