Splunk unknown stable spl

Detect Remote Access Software Usage FileInfo

The following analytic detects the execution of processes with file or code signing attributes from known remote access software within the environment. It leverages Sysmon EventCode 1 data and cross-references a lookup table of remote access utilities such as AnyDesk, GoToMyPC, LogMeIn, and TeamViewer. This activity is significant as adversaries often use these tools to maintain unauthorized remote access. If confirmed malicious, this could allow attackers to persist in the environment, potentially leading to data exfiltration or further compromise of the network.

View Source

Detection Logic

`sysmon` EventCode=1

[
| inputlookup remote_access_software
| search file_info!=""
| rename file_info as Product
| table Product
]
| stats count min(_time) as firstTime
              max(_time) as lastTime
              values(Company) as Company
              values(Product) as Product

  BY action dest original_file_name
     parent_process parent_process_exec parent_process_guid
     parent_process_id parent_process_name parent_process_path
     process process_exec process_guid
     process_hash process_id process_integrity_level
     process_name process_path user
     user_id vendor_product
| lookup local=t remote_access_software file_info as Product OUTPUT app as signature, category, reference, description
| `security_content_ctime(firstTime)`
| `security_content_ctime(lastTime)`
| `remote_access_software_usage_exceptions`
| `detect_remote_access_software_usage_fileinfo_filter`

False Positives

  • ⚠ Known or approved applications used by the organization or usage of built-in functions. Known false positives can be added to the remote_access_software_usage_exception.csv lookup to globally suppress these situations across all remote access content

Field Validations

Loading…

Comments (0)

Loading comments...