Microsoft Sentinel high experimental kql
SAP BTP - Cloud Integration JDBC data source changes
Identifies deployment and undeployment of JDBC data source configurations in SAP Cloud Integration. JDBC data sources contain database connection credentials and configuration that enable integration flows to access backend databases. Unauthorized JDBC data source manipulation could indicate: - Attacker adding rogue database connections for data exfiltration - Credential theft by accessing stored database passwords - Modification of connection strings to redirect traffic to attacker-controlled systems
Detection Logic
SAPBTPAuditLog_CL
| where Category == "audit.security-events"
| extend data_s = tostring(Message.data),
ipAddress = tostring(Message.ip)
| extend parsedData = parse_json(data_s)
| extend action = tostring(parsedData.action),
objectType = tostring(parsedData.objectType),
objectId = tostring(parsedData.objectId)
| where objectType == "Data Source"
| where action in ("PasswordStore", "PasswordDelete")
| extend normalizedAction = case(
action == "PasswordStore", "deployed",
action == "PasswordDelete", "undeployed",
action
)
| extend MessageText = strcat("JDBC data source '", objectId, "' was ", normalizedAction)
| project
UpdatedOn,
UserName,
MessageText,
DataSourceName = objectId,
Action = action,
Tenant,
ipAddress,
CloudApp = "SAP Cloud Integration"
| extend AccountName = split(UserName, "@")[0], UPNSuffix = split(UserName, "@")[1] Field Validations
Loading…
Comments (0)
Loading comments...