Microsoft Sentinel medium experimental kql

Check Point Exposure Management - Argos alerts to incidents

Creates a Microsoft Sentinel incident for each Check Point Exposure Management alert that reaches the argsentdc_CL table as open or acknowledged for the first time. Each result becomes its own alert, and ref_id is surfaced as a Custom Detail so the Exporter, ManualStatusUpdate and InboundStatusSync playbooks can map the incident back to the originating Argos alert. The CCP data connector polls on update_date, so every change to an Argos alert adds a new row for the same ref_id. Only the first open or acknowledged row creates an incident; later rows are status updates, which the Check_Point_EM_InboundStatusSync playbook applies to the existing incident. An alert counts as already seen when it had an open or acknowledged row ingested more than 20 minutes earlier. Only alerts created within the 47-hour lookback are considered, which is the longest lookback Microsoft Sentinel allows for a rule that runs every 5 minutes. Every earlier row of such an alert falls inside the same lookback, so the already-seen check is complete and an update can never open a second incident. An alert created more than 47 hours before it first reaches the table does not get an incident. The ingestion_time bound limits each row to the few runs its arrival window covers, because the DCR maps update_date into TimeGenerated and a row becomes queryable several minutes after that timestamp. Repeats within that window are folded into one incident by grouping on the ref_id custom detail.

View Source

Detection Logic

let ArrivalWindow = 20m;
let Lookback = 47h;
let SeenBefore = argsentdc_CL
| where TimeGenerated > ago(Lookback)
| where ingestion_time() <= ago(ArrivalWindow)
| where status in ("open", "acknowledged")
| distinct ref_id = tostring(ref_id);
argsentdc_CL
| where TimeGenerated > ago(Lookback)
| where ingestion_time() > ago(ArrivalWindow)
| summarize arg_max(TimeGenerated, *) by ref_id = tostring(ref_id)
| where status in ("open", "acknowledged")
| where todatetime(created_date) > ago(Lookback)
| join kind=leftanti SeenBefore on ref_id
| extend SentinelSeverity = case(
    severity in ("very_high", "critical"), "High",
    severity == "high", "High",
    severity == "medium", "Medium",
    severity == "low", "Low",
    "Informational")
| project TimeGenerated,
          RefId = ref_id,
          AlertTitle = tostring(event_title),
          AlertDescription = tostring(description),
          OriginalSeverity = tostring(severity),
          SentinelSeverity,
          Confidence = tostring(confidence),
          EventType = tostring(event_type),
          Category = tostring(category),
          Recommendation = tostring(recommendation)

Field Validations

Loading…

Comments (0)

Loading comments...