Elastic low stable kql

Unusual Base64 Encoding/Decoding Activity

This rule leverages ESQL to detect unusual base64 encoding/decoding activity on Linux systems. Attackers may use base64 encoding/decoding to obfuscate data, such as command and control traffic or payloads, to evade detection by host- or network-based security controls. ESQL rules have limited fields available in its alert documents. Make sure to review the original documents to aid in the investigation of this alert.

View Source

Detection Logic

from logs-endpoint.events.process-* metadata _id, _index, _version
| mv_expand event.action
| where
    host.os.type == "linux" and
    event.type == "start" and
    event.action == "exec" and (
        (
            process.name in ("base64", "base64plain", "base64url", "base64mime", "base64pem", "base32", "base16") and
            (process.args like "--d*" or process.args like "-d*")
        ) or
        (
            process.name == "openssl" and
            process.args == "enc" and
            process.args in ("-d", "-base64", "-a")
        ) or
        (
            process.name like "python*" and (
                (
                    process.args == "base64" and
                    process.args in ("-d", "-u", "-t")
                ) or
                (
                    process.args == "-c" and
                    process.command_line like "*base64*" and
                    process.command_line like "*b64decode*"
                )
            )
        ) or
        (
            process.name like "perl*" and
            process.command_line like "*decode_base64*"
        ) or
        (
            process.name like "ruby*" and
            process.args == "-e" and
            process.command_line like "*Base64.decode64*"
        )
    )
| keep
    @timestamp,
    _id,
    _index,
    _version,
    host.os.type,
    event.type,
    event.action,
    process.name,
    process.args,
    process.command_line,
    process.parent.name,
    process.parent.command_line,
    agent.id,
    host.name,
    data_stream.dataset,
    data_stream.namespace
| stats
    Esql.event_count = count(),
    Esql.process_parent_name_values = values(process.parent.name),
    Esql.process_parent_command_line_values = values(process.parent.command_line),
    Esql.agent_id_count_distinct = count_distinct(agent.id),
    Esql.host_name_values = values(host.name),
    Esql.agent_id_values = values(agent.id),
    Esql.data_stream_dataset_values = values(data_stream.dataset),
    Esql.data_stream_namespace_values = values(data_stream.namespace)
    by process.name, process.command_line
| where
    Esql.agent_id_count_distinct == 1 and
    Esql.event_count < 15
| sort Esql.event_count asc

// Extract unique values to ECS fields for alerts exclusion
| eval agent.id = mv_min(Esql.agent_id_values),
       host.name = mv_min(Esql.host_name_values)
| keep agent.id, host.name, process.name, process.command_line, Esql.*

Field Validations

Loading…

Comments (0)

Loading comments...