Suspicious MS Office Child Process

process where host.os.type == "windows" and event.type == "start" and
  process.parent.name : (
      "eqnedt32.exe", "excel.exe", "fltldr.exe", "msaccess.exe",
      "mspub.exe", "powerpnt.exe", "winword.exe", "outlook.exe"
  ) and
  process.name : (
      "Microsoft.Workflow.Compiler.exe", "arp.exe", "atbroker.exe", "bginfo.exe", "bitsadmin.exe", "cdb.exe",
      "certutil.exe", "cmd.exe", "cmstp.exe", "control.exe", "cscript.exe", "csi.exe", "dnx.exe", "dsget.exe",
      "dsquery.exe", "forfiles.exe", "fsi.exe", "ftp.exe", "gpresult.exe", "hostname.exe", "ieexec.exe", "iexpress.exe",
      "installutil.exe", "ipconfig.exe", "mshta.exe", "msxsl.exe", "nbtstat.exe", "net.exe", "net1.exe", "netsh.exe",
      "netstat.exe", "nltest.exe", "odbcconf.exe", "ping.exe", "powershell.exe", "pwsh.exe", "qprocess.exe",
      "quser.exe", "qwinsta.exe", "rcsi.exe", "reg.exe", "regasm.exe", "regsvcs.exe", "regsvr32.exe", "sc.exe",
      "schtasks.exe", "systeminfo.exe", "tasklist.exe", "tracert.exe", "whoami.exe", "wmic.exe", "wscript.exe",
      "xwizard.exe", "explorer.exe", "rundll32.exe", "hh.exe", "msdt.exe"
  ) and
  not (
    process.parent.name : "outlook.exe" and
    process.name : "rundll32.exe" and
    process.args : "shell32.dll,Control_RunDLL" and
    process.args : "srchadmin.dll"
  )