Elastic medium stable eql
Remotely Started Services via RPC
Identifies remote execution of Windows services over remote procedure call (RPC). This could be indicative of lateral movement, but will be noisy if commonly done by administrators.
Detection Logic
sequence with maxspan=1s
[network where host.os.type == "windows" and process.name : "services.exe" and
network.direction : ("incoming", "ingress") and network.transport == "tcp" and
source.port >= 49152 and destination.port >= 49152 and source.ip != "127.0.0.1" and source.ip != "::1"
] by host.id, process.entity_id
[process where host.os.type == "windows" and
event.type == "start" and process.parent.name : "services.exe" and
not (process.executable : "?:\\Windows\\System32\\msiexec.exe" and process.args : "/V") and
not process.executable : (
"?:\\Pella Corporation\\OSCToGPAutoService\\OSCToGPAutoSvc.exe",
"?:\\Pella Corporation\\Pella Order Management\\GPAutoSvc.exe",
"?:\\Pella Corporation\\Pella Order Management\\GPAutoSvc.exe",
"?:\\Program Files (x86)\\*.exe",
"?:\\Program Files\\*.exe",
"?:\\Windows\\ADCR_Agent\\adcrsvc.exe",
"?:\\Windows\\AdminArsenal\\PDQ*.exe",
"?:\\Windows\\CAInvokerService.exe",
"?:\\Windows\\ccmsetup\\ccmsetup.exe",
"?:\\Windows\\eset-remote-install-service.exe",
"?:\\Windows\\ProPatches\\Scheduler\\STSchedEx.exe",
"?:\\Windows\\PSEXESVC.EXE",
"?:\\Windows\\RemoteAuditService.exe",
"?:\\Windows\\servicing\\TrustedInstaller.exe",
"?:\\Windows\\System32\\certsrv.exe",
"?:\\Windows\\System32\\sppsvc.exe",
"?:\\Windows\\System32\\srmhost.exe",
"?:\\Windows\\System32\\svchost.exe",
"?:\\Windows\\System32\\taskhostex.exe",
"?:\\Windows\\System32\\upfc.exe",
"?:\\Windows\\System32\\vds.exe",
"?:\\Windows\\System32\\VSSVC.exe",
"?:\\Windows\\System32\\wbem\\WmiApSrv.exe",
"?:\\Windows\\SysWOW64\\NwxExeSvc\\NwxExeSvc.exe",
"?:\\Windows\\Veeam\\Backup\\VeeamDeploymentSvc.exe",
"?:\\Windows\\VeeamLogShipper\\VeeamLogShipper.exe",
"?:\\Windows\\VeeamVssSupport\\VeeamGuestHelper.exe"
)] by host.id, process.parent.entity_id Field Validations
Loading…
Comments (0)
Loading comments...