Elastic high stable eql
Potential System Tampering via File Modification
Identifies attempts to delete or modify critical files used during the boot process to prevent the system from booting. This may indicate a destructive attack behavior.
Detection Logic
file where host.os.type == "windows" and event.type in ("change", "deletion") and
file.name : ("winload.exe", "winload.efi", "ntoskrnl.exe", "bootmgr") and
file.path : ("?:\\Windows\\*", "\\Device\\HarddiskVolume*\\Windows\\*") and
not process.executable : (
"?:\\Windows\\System32\\poqexec.exe",
"?:\\Windows\\System32\\wbengine.exe",
"?:\\Windows\\WinSxS\\???64_microsoft-windows-servicingstack_*\\tiworker.exe"
) and
not file.path : (
"?:\\Windows\\WinSxS\\Temp\\InFlight\\*",
"?:\\Windows\\SoftwareDistribution\\Download*",
"?:\\Windows\\WinSxS\\amd64_microsoft-windows*",
"?:\\Windows\\SystemTemp\\*",
"?:\\Windows\\Temp\\????????.???\\*",
"?:\\Windows\\Temp\\*\\amd64_microsoft-windows-*",
"\\Device\\HarddiskVolume*\\Windows\\SoftwareDistribution\\Download*",
"?:\\Windows\\Temp\\BootImages\\{*}\\mount\\Windows\\*"
) Field Validations
Loading…
Comments (0)
Loading comments...