Elastic medium stable eql
Potential Linux Hack Tool Launched
Monitors for the execution of different processes that might be used by attackers for malicious intent. An alert from this rule should be investigated further, as hack tools are commonly used by blue teamers and system administrators as well.
Detection Logic
process where host.os.type == "linux" and event.type == "start" and
event.action in ("exec", "exec_event", "start", "ProcessRollup2", "executed", "process_started") and
(
process.name in~ (
// exploitation frameworks
"crackmapexec", "msfconsole", "msfvenom", "sliver-client", "sliver-server", "havoc",
// network scanners (nmap left out to reduce noise)
"zenmap", "nuclei", "netdiscover", "legion",
// web enumeration
"gobuster", "dirbuster", "dirb", "wfuzz", "ffuf", "whatweb", "eyewitness",
// web vulnerability scanning
"wpscan", "joomscan", "droopescan", "nikto",
// exploitation tools
"sqlmap", "commix", "yersinia",
// cracking and brute forcing
"john", "hashcat", "hydra", "ncrack", "cewl", "fcrackzip", "rainbowcrack",
// host and network
"linenum.sh", "linpeas.sh", "pspy32", "pspy32s", "pspy64", "pspy64s", "binwalk", "evil-winrm",
"linux-exploit-suggester-2.pl", "linux-exploit-suggester.sh", "panix.sh"
) or
(
process.name : "python*" and
process.args : ("*sqlmap.py", "*crackmapexec", "*commix.py")
) or
(
process.name : "ruby*" and process.args : "*wpscan"
) or
(
process.name in~ ("bash", "dash", "sh", "zsh", "ksh", "fish", "busybox") and
process.args : ("*linenum.sh*", "*linpeas.sh*", "*linux-exploit-suggester.sh*", "*panix.sh*")
) or
(
process.name : "perl*" and process.args : "*linux-exploit-suggester-2.pl"
)
) Field Validations
Loading…
Comments (0)
Loading comments...