Elastic high stable eql

Potential Execution via FileFix Phishing Attack

Identifies the execution of Windows commands or downloaded files via the browser's dialog box. Adversaries may use phishing to instruct the victim to copy and paste malicious commands for execution via crafted phishing web pages.

View Source

Detection Logic

process where host.os.type == "windows" and event.type == "start" and
 process.parent.args == "--message-loop-type-ui" and process.parent.args == "--service-sandbox-type=none" and
 (
  process.name : ("pwsh.exe", "powershell.exe", "curl.exe", "msiexec.exe", "mshta.exe", "wscript.exe", "cscript.exe", "rundll32.exe", "certutil.exe", "certreq.exe") or
  process.executable : "?:\\Users\\*\\Downloads\\*"
  ) and
not (
    process.name : "rundll32.exe" and
    process.args : (
      "ndfapi.dll,NdfRunDllDiagnoseWithAnswerFile",
      "shwebsvc.dll,AddNetPlaceRunDll",
      "?:\\WINDOWS\\Installer\\MSI*.tmp,zzzzInvokeManagedCustomActionOutOfProc",
      "*cryptext.dll,CryptExtOpenCER",
      "*cryptext.dll,CryptExtOpenCRL",
      "*cryptext.dll,CryptExtOpenPKCS7",
      "*cryptext.dll,CryptExtAddPFX",
      "?:\\Program Files\\Windows Photo Viewer\\PhotoViewer.dll,*",
      "?:\\WINDOWS\\*\\hotplug.dll,HotPlugSafeRemovalDriveNotification"
    )
  ) and
  not (process.name : "certutil.exe" and process.args : "-hashfile")

Field Validations

Loading…

Comments (0)

Loading comments...