Elastic medium stable kql
High Number of Egress Network Connections from Unusual Executable
This rule detects a high number of egress network connections from an unusual executable on a Linux system. This could indicate a command and control (C2) communication attempt, a brute force attack via a malware infection, or other malicious activity. ESQL rules have limited fields available in its alert documents. Make sure to review the original documents to aid in the investigation of this alert.
Detection Logic
from logs-endpoint.events.network-* metadata _id, _index, _version
| mv_expand event.action
| where
host.os.type == "linux" and
event.type == "start" and
event.action == "connection_attempted" and
(
process.executable like "/tmp/*" or
process.executable like "/var/tmp/*" or
process.executable like "/dev/shm/*" or
process.executable like "/var/log/*" or
process.executable like "/sys/*" or
process.executable like "/media/*" or
process.executable like "/proc/*" or
process.executable like "/var/backups/*" or
process.executable like "/var/mail/*" or
process.executable like "/var/spool/*" or
process.executable like "./*" or
process.name like ".*"
) and
not (
cidr_match(destination.ip,
"10.0.0.0/8", "127.0.0.0/8", "169.254.0.0/16", "172.16.0.0/12",
"192.0.0.0/24", "192.0.0.29/32", "192.0.0.8/32", "192.0.0.9/32",
"192.0.0.10/32", "192.0.0.170/32", "192.0.0.171/32", "192.0.2.0/24",
"192.31.196.0/24", "192.52.193.0/24", "192.168.0.0/16", "192.88.99.0/24",
"224.0.0.0/4", "100.64.0.0/10", "192.175.48.0/24", "198.18.0.0/15",
"198.51.100.0/24", "203.0.113.0/24", "240.0.0.0/4", "::1", "FE80::/10", "FF00::/8"
) or
process.executable like "/tmp/newroot/*" or
process.executable like "/tmp/.mount*" or
process.executable like "/tmp/go-build*"
)
| keep
@timestamp,
_id,
_index,
_version,
host.os.type,
event.type,
event.action,
process.name,
process.executable,
destination.ip,
agent.id,
host.name,
data_stream.dataset,
data_stream.namespace
| stats
Esql.event_count = count(),
Esql.agent_id_count_distinct = count_distinct(agent.id),
Esql.host_name_values = values(host.name),
Esql.agent_id_values = values(agent.id),
Esql.data_stream_dataset_values = values(data_stream.dataset),
Esql.data_stream_namespace_values = values(data_stream.namespace)
by process.executable
| where
Esql.agent_id_count_distinct == 1 and
Esql.event_count > 15
// Extract unique values to ECS fields for alerts exclusion
| eval agent.id = mv_min(Esql.agent_id_values),
host.name = mv_min(Esql.host_name_values)
| sort Esql.event_count asc
| keep agent.id, host.name, process.executable, Esql.* Field Validations
Loading…
Comments (0)
Loading comments...