Elastic medium stable kql

GCP Vertex AI Role Granted to Principal

Identifies an IAM policy change on a Google Cloud project, folder, or organization that grants a Vertex AI role (`roles/aiplatform.*`) to a principal. Vertex AI roles control who can invoke models, deploy endpoints, run agents, and read prompt and training data. An adversary who has gained IAM administration rights can grant a Vertex AI role to an identity they control to keep model access after the original foothold is removed, or to run LLMjacking workloads under the victim's billing. Google-managed service agent roles are excluded because Google grants them automatically when the API is enabled.

View Source

Detection Logic

data_stream.dataset: "gcp.audit"
  and event.action: (
    "SetIamPolicy" or
    google.cloud.resourcemanager.v*.Folders.SetIamPolicy or
    google.cloud.resourcemanager.v*.Organizations.SetIamPolicy or
    google.cloud.resourcemanager.v*.Projects.SetIamPolicy
  )
  and not event.outcome: "failure"
  and gcp.audit.service_data.policy_delta.binding_deltas:{
    action: "ADD" and
    role: (roles/aiplatform.* and not (*ServiceAgent or *serviceAgent))
  }

False Positives

  • ⚠ Platform or ML engineering teams granting Vertex AI access to new users and service accounts. Confirm the grant against change records or the access request process.
  • ⚠ Infrastructure-as-code pipelines that manage project IAM bindings. Add exceptions for the service accounts that run these pipelines.

Field Validations

Loading…

Comments (0)

Loading comments...