Elastic medium stable eql
Entra ID OAuth PRT Issuance to Non-Managed Device Detected
Identifies when a user signs in with a refresh token using the Microsoft Authentication Broker (MAB) client, followed by a Primary Refresh Token (PRT) sign-in from the same device within 1 hour from an unmanaged device. This pattern may indicate that an attacker has successfully registered a device using ROADtx and transitioned from short-term token access to long-term persistent access via PRTs. Excluding access to the Device Registration Service (DRS) ensures the PRT is being used beyond registration, often to access Microsoft 365 resources like Outlook or SharePoint.
Detection Logic
sequence by azure.signinlogs.properties.user_id, azure.signinlogs.properties.device_detail.device_id with maxspan=1h
[authentication where
data_stream.dataset == "azure.signinlogs" and
azure.signinlogs.category == "NonInteractiveUserSignInLogs" and
azure.signinlogs.properties.app_id == "29d9ed98-a469-4536-ade2-f981bc1d605e" and
azure.signinlogs.properties.incoming_token_type == "refreshToken" and
azure.signinlogs.properties.device_detail.trust_type == "Azure AD joined" and
azure.signinlogs.properties.device_detail.device_id != null and
azure.signinlogs.properties.token_protection_status_details.sign_in_session_status == "unbound" and
azure.signinlogs.properties.user_type == "Member" and
azure.signinlogs.result_signature == "SUCCESS"
]
[authentication where
data_stream.dataset == "azure.signinlogs" and
azure.signinlogs.properties.incoming_token_type == "primaryRefreshToken" and
azure.signinlogs.properties.resource_display_name != "Device Registration Service" and
azure.signinlogs.result_signature == "SUCCESS" and
azure.signinlogs.properties.device_detail.is_managed != true
and not (
azure.signinlogs.properties.app_display_name == "Windows Sign In" or
user_agent.original == "Windows-AzureAD-Authentication-Provider/1.0"
)
] Field Validations
Loading…
Comments (0)
Loading comments...