Elastic high stable kql

AWS EKS RBAC Wildcard Elevation on Existing Role

Flags an existing Role or ClusterRole being changed (patch or update) to a wildcard on every API resource and verb. This may be indicative of a deliberate privilege expansion but may also be a nefarious attempt at privilege escalation.

View Source

Detection Logic

from logs-aws.eks_audit-* metadata _id, _index, _version
| where
  aws.eks.audit.objectRef.resource in ("roles", "clusterroles") and
  aws.eks.audit.verb in ("update", "patch") and
  `aws.eks.audit.annotations.authorization_k8s_io/decision` == "allow" and
  aws.eks.audit.level == "RequestResponse" and
  aws.eks.audit.stage == "ResponseComplete" and
  aws.eks.audit.sourceIPs is not null and
  not aws.eks.audit.sourceIPs in ("::1", "127.0.0.1") and
  KQL(""" aws.eks.audit.responseObject.rules.verbs:"*" and aws.eks.audit.responseObject.rules.resources:"*" """)
| keep user.name, user_agent.original, event.action, source.ip, aws.eks.audit.verb, aws.eks.audit.objectRef.resource, aws.eks.audit.objectRef.name, aws.eks.audit.requestURI, aws.eks.audit.user.username, aws.eks.audit.user.groups, `aws.eks.audit.annotations.authorization_k8s_io/decision`, event.original, _id, _version, _index, data_stream.namespace

False Positives

  • ⚠ Platform installers, GitOps controllers, and emergency break-glass roles sometimes ship or widen wildcard ClusterRoles; correlate with change records and narrow by user or service account when baselined.

Field Validations

Loading…

Comments (0)

Loading comments...