Elastic Defend high stable eql

UAC Bypass Attempt via DismCore DLL Side-Loading

Identifies attempts to bypass User Account Control (UAC) via DLL side-loading. Attackers may attempt to bypass UAC to stealthily execute code with elevated permissions.

View Source

Detection Logic

sequence with maxspan=60s
 [file where event.action : "rename" and process.name : ("dllhost.exe", "wusa.exe") and
  file.name : "DismCore.dll" and
  not file.path : ("?:\\Windows\\SoftwareDistribution\\*.dll", "?:\\Windows\\WinSxS\\*.dll")]
 [process where event.action == "start" and
  process.parent.name : "Dism.exe" and process.Ext.token.integrity_level_name == "high" and
  not process.executable :
           ("?:\\Windows\\System32\\WerFault.exe",
            "?:\\Windows\\SysWOW64\\WerFault.exe",
            "?:\\Windows\\System32\\wermgr.exe",
            "?:\\Windows\\SysWOW64\\wermgr.exe",
            "?:\\Windows\\System32\\conhost.exe",
            "?:\\Windows\\SysWOW64\\conhost.exe") and
  not (process.pe.original_file_name == "DismHost.exe" and process.code_signature.trusted == true and
       process.code_signature.subject_name : "Microsoft *")]

Field Validations

Loading…

Comments (0)

Loading comments...