Suspicious Execution from INET Cache

process where event.action == "start" and
  process.parent.name : ("explorer.exe", "winrar.exe", "7zFM.exe", "Bandizip.exe") and
  (process.command_line : "*\\AppData\\Local\\Microsoft\\Windows\\INetCache\\IE\\*" or
   process.executable : "?:\\Users\\*\\AppData\\Local\\Microsoft\\Windows\\INetCache\\IE\\*") and
  not (process.code_signature.subject_name :
             ("Google LLC", "Google Inc","Mozilla Corporation", "Zhuhai Kingsoft Office Software Co., Ltd.",
              "VideoLAN") and
       process.code_signature.trusted == true) and
  not (process.name : "rundll32.exe" and
       process.args : ("cryptext.dll,CryptExtAddCER", "cryptext.dll,CryptExtOpenCER", "ieframe.dll,OpenUR", "C:\\Windows\\System32\\ieframe.dll,OpenURL")) and
  not process.executable :
                 ("?:\\Program Files\\*.exe",
                  "?:\\Program Files (x86)\\*.exe",
                  "?:\\Windows\\System32\\mspaint.exe",
                  "?:\\Windows\\System32\\notepad.exe",
                  "C:\\Windows\\SysWOW64\\Codecs\\mpc-hc.exe",
                  "?:\\Windows\\CCM\\*.exe",
                  "?:\\Users\\*\\AppData\\Local\\Programs\\Microsoft VS Code\\Code.exe") and
  not (process.code_signature.trusted == true and not process.code_signature.subject_name : "Microsoft*")