Elastic Defend high stable eql
Suspicious Execution from a Mounted Device
Identifies when a script interpreter or signed binary is launched via a non-standard working directory. An attacker may use this technique to evade defenses.
Detection Logic
sequence with maxspan=1m
[file where event.action == "creation" and file.extension : "lnk" and
process.name : "explorer.exe" and
file.path : ("?:\\Users\\*\\AppData\\Roaming\\Microsoft\\Windows\\Recent\\*.vhd.lnk",
"?:\\Users\\*\\AppData\\Roaming\\Microsoft\\Windows\\Recent\\*.iso.lnk")] by process.entity_id
[process where event.action == "start" and process.executable : "C:\\*" and
(process.working_directory : "?:\\" and not process.working_directory : "C:\\") and process.parent.name : "explorer.exe" and
process.name : ("rundll32.exe", "mshta.exe", "powershell.exe", "pwsh.exe", "cmd.exe", "regsvr32.exe", "cscript.exe",
"wscript.exe", "wmic.exe", "msbuild.exe", "regsvcs.exe", "installutil.exe", "cmstp.exe", "msxsl.exe",
"Microsoft.Workflow.Compiler.exe", "wuauclt.exe") and
/* Issue #316 */
process.args_count >= 2] by process.parent.entity_id Field Validations
Loading…
Comments (0)
Loading comments...