Elastic Defend high stable eql

Suspicious API Call via Windows Script Interpreter

Identifies a suspicious managed code hosting process which could indicate code injection or other form of suspicious code execution via Windows scripts.

View Source

Detection Logic

api where
  process.name : ("wscript.exe", "cscript.exe", "mshta.exe", "cmstp.exe", "msxsl.exe", "mmc.exe") and
  process.Ext.api.name : ("VirtualAlloc", "MapViewOfFile*") and
  process.Ext.api.metadata.target_address_name : "?*" and process.Ext.api.parameters.protection == "RWX" and
  process.thread.Ext.call_stack_final_user_module.name in ("clr.dll", "mscoreei.dll") and
  process.thread.Ext.call_stack_summary : ("*
| clr.dll
| jscript*", "*
| clr.dll
| vbscript.dll
| msxml?.dll
| *") and
  not process.Ext.api.metadata.target_address_name in ("clr.dll", "gdi32full.dll") and
  process.Ext.api.parameters.size != 296 and
  not process.parent.executable :
               ("?:\\IPeople\\Script\\IPScriptDirector.exe",
                "?:\\Program Files\\Microsoft System Center\\Operations Manager\\Server\\MonitoringHost.exe",
                "?:\\Program Files\\Microsoft System Center\\Operations Manager\\Server\\MonitoringHost.exe",
                "C:\\Program Files (x86)\\DarkWebAdvisorsAgent\\PCPitstopScheduleService.exe",
                "C:\\Program Files (x86)\\TelesystemAgent\\PCPitstopScheduleService.exe") and
  not (process.executable : "C:\\Windows\\SysWOW64\\cscript.exe" and process.parent.executable : "C:\\Windows\\SysWOW64\\cmd.exe" and
       process.command_line like "cscript  //B scan.wsf *" and user.id == "S-1-5-18") and
  not (process.executable : "C:\\Windows\\System32\\mmc.exe" and
       process.thread.Ext.call_stack_summary like "ntdll.dll
| *
| mswb7.dll
| clr.dll
| jscript.dll
| mmcndmgr.dll
| mmc.exe*") and
  not process.command_line :
             ("\"C:\\Windows\\System32\\cscript.exe\" //B //Nologo C:\\Windows\\Options\\SWD\\MapHomeDrive_1_0_0.vbs",
              "C:\\WINDOWS\\System32\\WScript.exe \"M:\\DOH\\Data Exchange\\OCFS\\Severe Maternal Morbidity\\EGScript1.vbs\" ",
              "cscript.exe  //T:120 //U //Nologo \"C:\\Program Files (x86)\\Site24x7\\WinAgent\\monitoring\\conf\\scripts\\topprocess.vbs\" 2 ")

Field Validations

Loading…

Comments (0)

Loading comments...