Elastic Defend high stable eql

Scheduled Task Creation from Suspicious Parent

Identifies the creation of a scheduled task from a suspicious parent process. This behavior is consistent with an adversary attempting to establish persistence.

View Source

Detection Logic

sequence with maxspan=1m
 [process where event.action == "start" and
  (
   (process.Ext.device.product_id : ("Virtual DVD-ROM", "Virtual Disk", "USB *") and
    not process.executable : "C:\\*") or

   ((process.Ext.relative_file_creation_time <= 900 or process.Ext.relative_file_name_modify_time <= 900) and
     not process.code_signature.status : "trusted") or

   (process.executable :
	        ("?:\\Users\\*\\AppData\\*",
	         "?:\\Users\\*\\Downloads\\*",
	         "?:\\Users\\*\\Desktop\\*",
	         "?:\\Users\\Public\\*",
	         "\\Device\\Mup*") and not process.code_signature.status : "trusted")
   ) and 
   not process.executable : "?:\\Program Files\\WinCompose\\wincompose.exe" and 
   not process.hash.sha256 : "fef078893ac6b23a7412b0b757f6e24631db84133cc420a9844e1e64212e4478"] by process.entity_id
  [process where event.action == "start" and
   (process.pe.original_file_name : "schtasks.exe" or process.name : "schtasks.exe") and
   not process.Ext.token.integrity_level_name == "system" and
   process.args : ("/create", "-create") and process.args : "/tr" and
   not process.command_line : ("*:\\Program Files\\*", "*:\\Program Files (x86)\\*")] by process.parent.entity_id

Field Validations

Loading…

Comments (0)

Loading comments...