Elastic Defend high stable eql

Regsvr32 Scriptlet Execution

Identifies the native Windows tool, regsvr32.exe, executing a scriptlet file. This can allow an attacker to bypass whitelisting and run arbitrary scripts.

View Source

Detection Logic

process where event.action == "start" and
 (process.pe.original_file_name : "regsvr32.exe" or process.name : "regsvr32.exe") and
  (
    (process.command_line : "*scrobj*" and process.command_line : ("* /i:*", "* -i:*", "*.sct*")) or
      /* attackers may rename scrobj.dll */
      (
        process.command_line : "* /u*" and
        process.command_line :
          (
            "* /i:C:\\*",
            "* /i:\"C:\\*",
            "* -i:C:\\*",
            "* -i:\"C:\\*",
            "* /i:*http*",
            "* -i:*http*"
          )
      )
  ) and
  /* Issue #326 */
  not (process.Ext.token.integrity_level_name == "system" and not process.command_line : "*scrobj.dll*") and
  not process.command_line : ("*:\\Program Files\\*", "*:\\Program Files (x86)\\*") and
  not (process.parent.executable : ("?:\\Windows\\SysWOW64\\msiexec.exe", "?:\\Windows\\system32\\msiexec.exe") and
      not process.command_line : "*scrobj.dll*")

Field Validations

Loading…

Comments (0)

Loading comments...