Elastic Defend high stable eql

Potential Linux Tunneling via Cloudflared

Identifies the use of Cloudflare Tunnel (cloudflared) to expose a local service or create an outbound tunnel. Adversaries may abuse quick tunnels or named tunnels to proxy C2 traffic or exfiltrate data through Cloudflare's edge while evading direct connection blocking.

View Source

Detection Logic

process where event.type == "start" and event.action == "exec" and
(
  (
    process.name == "cloudflared" or
    process.args in ("--url", "-url", "--token", "-token")
  ) and
  process.args == "tunnel" 
) and not (
  process.args in ("info", "delete") or
  process.parent.executable in ("/usr/lib/systemd/systemd", "/lib/systemd/systemd", "./runc", "/usr/bin/runc") or
  process.parent.executable like ("/var/lib/rancher/*/bin/runc", "/home/*/.nvm/versions/node/*/bin/node") or
  process.parent.command_line == "runc init" or
  process.parent.args in ("/etc/init.d/cloudflared", "/usr/bin/crun") or
  process.executable in ("/usr/bin/podman", "/usr/bin/docker") or
  (process.parent.executable == "/bin/busybox" and process.parent.args like "/home/*/tunnel-exit-node.sh") or
  (process.name == "echo" and process.parent.name == "xargs" and process.parent.command_line == "xargs --null") or
  process.working_directory like "/home/*/Desktop/*" or
  (
    process.executable == "/builds/qa/ai-test-runner/helpers/modules/cloudflared-linux-amd64" and
    process.working_directory == "/builds/qa/ai-test-runner"
  ) or
  (
    process.executable == "/app/ai-test-generation/helpers/modules/cloudflared-linux-amd64" and
    process.working_directory == "/app/ai-test-generation"
  ) or
  process.parent.executable like "*/node_modules/opencode-ai/bin/opencode*"
)

Field Validations

Loading…

Comments (0)

Loading comments...