Elastic Defend high stable eql

Potential DLL SideLoad via a Renamed Signed Binary

Identifies attempts to load an unsigned DLL from a mounted virtual disk (.iso, .vhd) and by a renamed signed binary. This may indicate an attempt to sideload a malicious DLL to stealthily execute code for initial access.

View Source

Detection Logic

/* Signed PE with OriginalFileName different than process.name as potential target from a malicious ISO/DMG/VHD archive */

sequence by process.entity_id with maxspan=1m

 [process where event.action == "start" and process.pe.original_file_name != null and
  (process.code_signature.trusted == true or process.pe.original_file_name : ("calc.exe", "ClientConsole.EXE")) and
  not startswith~(process.name, process.pe.original_file_name) and
  (process.Ext.device.product_id : ("Virtual DVD-ROM", "Virtual Disk") and not process.executable : "C:\\*") and

  /* ba802fb2-f183-420e-947b-da5ce0c74dd3 */
  not process.code_signature.subject_name : "Microsoft *"]
 [library where
  (dll.Ext.device.product_id : ("Virtual DVD-ROM", "Virtual Disk") and not dll.path : "C:\\*") and
  not dll.code_signature.status : ("trusted", "errorExpired", "errorCode_endpoint*", "errorChaining") and
  not startswith~(dll.name, process.name)]

Field Validations

Loading…

Comments (0)

Loading comments...