Elastic Defend high stable eql

Nohup Execution followed by Outbound Network Connection

Detects the execution of the Nohup utility pointing to a suspicious or malicious executable path followed by pushing the execution to the background using the "&". Threat actors will utilize the Nohup utility to execute their payloads in a variety of ways but specifically within initial access installer scripts and shell profile persistence. This activity should be considered highly abnormal or malicious.

View Source

Detection Logic

sequence by process.parent.entity_id with maxspan=30s
[process where event.type == "start" and 
  process.name == "nohup" and
  ((process.command_line like~ ("*/tmp/*",
                                "*/var/tmp/*",
                                "*/private/var/tmp/*",
                                "*/var/folders/*", 
                                "*/Users/Shared/*", 
                                "*/Library/*", 
                                "*/var/root/*", 
                                "*/usr/local/bin/*", 
                                "*/Applications/*")) or
   (process.args like~ "npm" and process.args like~ "install")) and
  process.parent.name like~ ("bash", "sh", "zsh", "tclsh*", "terminal", "python*", "osascript") and
  not process.Ext.effective_parent.executable == "/Applications/SteelSeries GG/SteelSeries GG.app/Contents/MacOS/SteelSeries GG" and
  not (process.parent.name in ("zsh", "bash", "sh") and process.parent.command_line : (
    "*/.claude/shell-snapshots/*",
    "*/.claude-personal/shell-snapshots/*",
    "*/.codex/shell_snapshots/*",
    "*/.cursor/shell-snapshots/*",
    "*__CURSOR_SANDBOX_ENV_RESTORE*")) and
  not process.command_line : (
    "*/tmp/claude/*",
    "*/private/tmp/claude/*",
    "*/private/tmp/claude-*/*",
    "*/Library/Application Support/Claude/local-agent-mode-sessions/*",
    "*/Library/Android/sdk/emulator/*")]
[network where event.type == "start" and
   not cidrmatch(destination.ip, 
       "240.0.0.0/4", "233.252.0.0/24", "224.0.0.0/4", "198.19.0.0/16", "192.18.0.0/15", 
       "192.0.0.0/24", "10.0.0.0/8", "127.0.0.0/8", "169.254.0.0/16", "172.16.0.0/12", 
       "192.0.2.0/24", "192.31.196.0/24", "192.52.193.0/24", "192.168.0.0/16", "192.88.99.0/24", 
       "100.64.0.0/10", "192.175.48.0/24", "198.18.0.0/15", "198.51.100.0/24", "203.0.113.0/24",
       "::1", "FE80::/10", "FF00::/8")]

Field Validations

Loading…

Comments (0)

Loading comments...