Elastic Defend high stable eql

Inhibit System Recovery via Signed Binary Proxy

Identifies the execution of Windows utilities to tamper with system recovery settings. Adversaries may delete or remove built-in operating system data and turn off services designed to aid in the recovery of a corrupted system and prevent recovery.

View Source

Detection Logic

process where event.action == "start" and
  descendant of [process where event.action == "start" and
                 process.name:
                    (
					 "rundll32.exe",
					 "cscript.exe",
					 "wscript.exe",
					 "regsvr32.exe",
					 "regasm.exe",
					 "regsvcs.exe",
					 "installutil.exe",
					 "mshta.exe",
					 "cmstp.exe",
					 "msxsl.exe",
					 "Microsoft.Workflow.Compiler.exe",
					 "ieexec.exe",
					 "iexpress.exe"
					 )]
  and
  (
    (process.pe.original_file_name : "wmic.exe" and process.command_line : "*shadowcopy*" and
	 process.command_line : "*delete*") or
    (process.pe.original_file_name : "vssadmin.exe" and process.command_line : "*shadows*" and
	 process.command_line : ("*delete*", "*resize*401*")) or
    (process.pe.original_file_name : "bcdedit.exe" and process.command_line : ("*bootstatuspolicy*", "*recoveryenabled*")) or
    (process.pe.original_file_name : "wbadmin.exe" and process.command_line : ("*catalog*", "*systemstatebackup*") and process.command_line : "*delete*")
  ) and
  not (process.name : "vssadmin.exe" and process.args : "Resize" and process.parent.executable : "?:\\Program Files\\Geni\\Insights\\GsAgent.exe")

Field Validations

Loading…

Comments (0)

Loading comments...