Execution of Commonly Abused Utilities via Explorer Trampoline

process where event.action == "start" and
  (
   process.name : ("cscript.exe", "wscript.exe", "rundll32.exe", "mshta.exe", "regsvr32.exe") or
   process.pe.original_file_name :
               ("cscript.exe",
                "wscript.exe",
                "rundll32.exe",
                "mshta.exe",
                "regsvr32.exe")
  ) and
  /* Explorer started via DCOM */
  process.parent.name : "explorer.exe" and process.parent.command_line : "*/factory,{75dff2b7-6936-4c06-a8bb-676a7b00b24b}*" and
  not
     (
      process.name : "rundll32.exe" and
      process.args : ("rundll32.exe*\\Users\\*\\AppData\\Local\\Cognitas\\CrossLink6\\csathl32.dll*",
                      /* Issue #340 */
                      "*dfshim.dll*ShOpenVerbApplication*",
                      "dfshim.dll,",
                      "?:\\WINDOWS\\system32\\hotplug.dll,HotPlugSafeRemovalDriveNotification",
                      "cryptext.dll,CryptExtOpen*",
                      "cryptext.dll,CryptExtAddCER",
                      "ndfapi.dll,NdfRunDllDiagnoseWithAnswerFile",
                      "shwebsvc.dll,AddNetPlaceRunDll",
                      "?:\\Program Files\\Windows Photo Viewer\\PhotoViewer.dll*",
                      "?:\\Windows\\system32\\hotplug.dll,HotPlugSafeRemovalDriveNotification",
                      "devmgr.dll,DeviceProperties_RunDLL",
                      "printui.dll,PrintUIEntryDPIAware",
                      "?:\\windows\\System32\\srchadmin.dll",
                      "fdprint,InvokeTask",
                      "cryptext.dll,CryptExtAddPFX",
                      "shell32.dll,SHCreateLocalServerRunDll",
                      "?:\\WINDOWS\\System32\\SHELL32.dll,RunAsNewUser_RunDLL", 
                      "?:\\WINDOWS\\system32\\spool\\DRIVERS\\x64\\3\\*",
                      "C:\\Program Files (x86)\\Stardock\\Fences\\FencesMenu64.dll,StartFences",
                      "C:\\Windows\\System32\\*.cpl")
      ) and
  not (process.name : ("wscript.exe", "cscript.exe") and
       process.args : ("\\\\*.vbs", "C:\\Robocopy\\robocopy_Mail_Config_Veeam.vbs", "C:\\Users\\*\\Documents\\*.vbs", "X:\\*.vbs", "W:\\*.vbs"))