Google Chronicle critical experimental yara-l
Google Safebrowsing File Contacts Tor Exit Node
A malicious file contacting a known Tor Exit Node.
Detection Logic
/*
* Copyright 2023 Google LLC
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* https://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES
OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
rule google_safebrowsing_file_contacts_tor_exit_node {
meta:
author = "Google Cloud Security"
description = "A malicious file contacting a known Tor Exit Node."
rule_id = "mr_f6733319-50b3-477e-bad6-96bb4c14c632"
rule_name = "Google Safebrowsing File Contacts Tor Exit Node"
tactic = "TA0011"
technique = "T1090.003"
type = "alert"
data_source = "microsoft defender atp, crowdstrike, microsoft sysmon"
severity = "Critical"
priority = "High"
events:
$network.metadata.event_type = "NETWORK_CONNECTION"
$network.principal.process.file.sha256 != ""
$network.principal.process.file.sha256 = $file_hash
$network.principal.hostname = $hostname
$network.target.ip = $ip
// Safe Browsing file hashes provided by GCTI Feed
$safebrowse.graph.metadata.product_name = "Google Safe Browsing"
$safebrowse.graph.metadata.entity_type = "FILE"
$safebrowse.graph.metadata.source_type = "GLOBAL_CONTEXT"
$safebrowse.graph.metadata.threat.category = "SOFTWARE_MALICIOUS"
$safebrowse.graph.entity.file.sha256 = $file_hash
// Tor IP listing provided by GCTI Feed
$gcti.graph.entity.artifact.ip = $ip
$gcti.graph.metadata.entity_type = "IP_ADDRESS"
$gcti.graph.metadata.source_type = "GLOBAL_CONTEXT"
$gcti.graph.metadata.threat.threat_feed_name = "Tor Exit Nodes"
$gcti.graph.metadata.vendor_name = "Google Cloud Threat Intelligence"
$gcti.graph.metadata.product_name = "GCTI Feed"
match:
$hostname over 1h
outcome:
$risk_score = 95
$event_count = count_distinct($network.metadata.id)
//added to populate alert graph with additional context
$principal_ip = array_distinct($network.principal.ip)
$target_ip = array_distinct($network.target.ip)
$principal_process_pid = array_distinct($network.principal.process.pid)
$principal_process_command_line = array_distinct($network.principal.process.command_line)
$principal_process_file_sha256 = array_distinct($network.principal.process.file.sha256)
$principal_process_file_full_path = array_distinct($network.principal.process.file.full_path)
$principal_process_product_specific_process_id = array_distinct($network.principal.process.product_specific_process_id)
$principal_process_parent_process_product_specific_process_id = array_distinct($network.principal.process.parent_process.product_specific_process_id)
//$target_process_pid = array_distinct($network.target.process.pid)
$target_process_command_line = array_distinct($network.target.process.command_line)
$target_process_file_sha256 = array_distinct($network.target.process.file.sha256)
$target_process_file_full_path = array_distinct($network.target.process.file.full_path)
$target_process_product_specific_process_id = array_distinct($network.target.process.product_specific_process_id)
$target_process_parent_process_product_specific_process_id = array_distinct($network.target.process.parent_process.product_specific_process_id)
$principal_user_userid = array_distinct($network.principal.user.userid)
$target_user_userid = array_distinct($network.target.user.userid)
condition:
$network and $gcti and $safebrowse
} Field Validations
Loading…
Comments (0)
Loading comments...