Google Chronicle high experimental yara-l
GCTI Tor Exit Nodes
Alert traffic destined for known Tor exit nodes
Detection Logic
/*
* Copyright 2023 Google LLC
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* https://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES
OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
rule gcti_tor_exit_nodes {
meta:
author = "Google Cloud Security"
description = "Alert traffic destined for known Tor exit nodes"
rule_id = "mr_1d31f0e4-8cd9-4fc2-ae87-e91a435fe34f"
rule_name = "GCTI Tor Exit Nodes"
tactic = "TA0011"
technique = "T1090.003"
type = "alert"
tags = "tor"
data_source = "crowdstrike, microsoft sysmon, microsoft defender atp"
severity = "High"
priority = "High"
events:
$network.metadata.event_type = "NETWORK_CONNECTION"
$network.security_result.action = "ALLOW"
$network.target.ip = $ip
// Tor IP listing provided by GCTI Feed
$gcti_feed.graph.entity.artifact.ip = $ip
$gcti_feed.graph.metadata.entity_type = "IP_ADDRESS"
$gcti_feed.graph.metadata.threat.threat_feed_name = "Tor Exit Nodes"
$gcti_feed.graph.metadata.product_name = "GCTI Feed"
$gcti_feed.graph.metadata.source_type = "GLOBAL_CONTEXT"
match:
$ip over 1h
outcome:
$risk_score = 85
$event_count = count_distinct($network.metadata.id)
$tor_geoip_country = array_distinct($network.target.ip_geo_artifact.location.country_or_region)
$tor_geoip_state = array_distinct($network.target.ip_geo_artifact.location.state)
// added to populate alert graph with additional context
$principal_ip = array_distinct($network.principal.ip)
// Commented out target.ip because it is already represented in graph as match variable. If match changes, can uncomment to add to results
//$target_ip = array_distinct($network.target.ip)
$principal_process_pid = array_distinct($network.principal.process.pid)
$principal_process_command_line = array_distinct($network.principal.process.command_line)
$principal_process_file_sha256 = array_distinct($network.principal.process.file.sha256)
$principal_process_file_full_path = array_distinct($network.principal.process.file.full_path)
$principal_process_product_specific_process_id = array_distinct($network.principal.process.product_specific_process_id)
$principal_process_parent_process_product_specific_process_id = array_distinct($network.principal.process.parent_process.product_specific_process_id)
$target_process_pid = array_distinct($network.target.process.pid)
$target_process_command_line = array_distinct($network.target.process.command_line)
$target_process_file_sha256 = array_distinct($network.target.process.file.sha256)
$target_process_file_full_path = array_distinct($network.target.process.file.full_path)
//$target_process_product_specific_process_id = array_distinct($network.target.process.product_specific_process_id)
//$target_process_parent_process_product_specific_process_id = array_distinct($network.target.process.parent_process.product_specific_process_id)
$principal_user_userid = array_distinct($network.principal.user.userid)
$target_user_userid = array_distinct($network.target.user.userid)
condition:
$network and $gcti_feed
} Field Validations
Loading…
Comments (0)
Loading comments...